      subroutine recombine(aavg,zbar,t,rho,cv,cvp,ca,cap,qrec)       
*
* Recombination neutrino rates of Kohyama, Itoh, Obama, & Mutoh,
* 1993, ApJ, 415, 267.
* These are much lower than Beaudet, Petrosian, & Salpeter rates,
* and are not believed to be important for white dwarf stars.
*
      implicit double precision(a-h,o-z)

      common/comp/amhyhe,amheca,x(4)
      real n

      n = 2.0
      zetfac = 1.579d+5 * zbar * zbar / t
*
* gnoofac for case where A/Z = 2 
* no H version
*
      gnoofac = 5.526d+7*rho/(t**1.5)
*
* H version
*
      if(x(1) .ne. 0.0)then
        gnoofac = gnoofac * (1.d0 + (0.992*x(1)/1.008))
      endif
*
* now determine gnoo from gnoofac via inverse of F-D integral
*
      gnoo = finv(gnoofac)
*
* if nu falls outside the range, exit
*
      if(gnoo.lt.-20.0 .or. gnoo.gt.10.0)then
        qrec = 0.d0
        return
      endif
*
* now compute Q from pieces
*
      qfac1 = (cv*cv + 1.5*ca*ca) + (n*(cvp*cvp +1.5*cap*cap))
      qfac2 = 2.649d-18 * zbar**14 * rho / aavg
      qfac3 = 1.d0 / (1.d0 + dexp(zetfac+gnoo))
*
* determine Q for recombination neutrinos. Qo for comparison to paper.
*
      qrec = qfac1*qfac2*qfac3*rjay(zetfac,gnoo)

      return      
      end 

************************************************************************

